Groovy DSL

Groovy DSL 是 Java DSL 的包装和扩展。我们在这里追求的主要目标是使 Spring Integration 在 Groovy 上的开发尽可能流畅和直接，同时与现有的 Java DSL 以及一些 Groovy 扩展或特定语言结构具有互操作性。该实现是 Groovy 支持模块的一部分。

您只需导入 import static org.springframework.integration.groovy.dsl.IntegrationGroovyDsl.integrationFlow 即可开始使用——这是一个包含 Groovy DSL 的重载工厂方法的类。

对于作为 lambda 的 IntegrationFlow 定义，我们通常不需要 Groovy 中的其他任何东西，只需像这样声明一个 bean：

@Bean
IntegrationFlow oddFlow() {
    { IntegrationFlowDefinition flow ->
	    flow.handle(Object, { p, h -> 'odd' })
    }
}

在这种情况下，Groovy 明白闭包应该被翻译成一个 IntegrationFlow 匿名实例，并且目标 Java DSL 处理器将此结构正确解析为 Java 对象。

作为上述构造的替代方案，并为了与下面解释的用例保持一致，spring-integration-groovy 模块提供了一个 Groovy 特定的 DSL，用于以 builder 模式样式声明集成流：

@Bean
flowLambda() {
    integrationFlow {
        filter String, { it == 'test' }, { id 'filterEndpoint' }
        wireTap integrationFlow {
            channel { queue 'wireTapChannel' }
        }
        delay {
		    messageGroupId 'delayGroup'
		    defaultDelay 100
        }
        transform {
		    transformer { it.toUpperCase() }
            expectedType String
        }
    }
}

这样一个全局的 integrationFlow() 函数期望一个 GroovyIntegrationFlowDefinition（IntegrationFlowDefinition 的 Groovy 包装器）的 builder 风格闭包，并生成一个常规的 IntegrationFlow lambda 实现。请参阅下面更多重载的 integrationFlow() 变体。

许多其他场景需要 IntegrationFlow 从数据源开始（例如 JdbcPollingChannelAdapter、JmsInboundGateway 或只是一个现有的 MessageChannel）。为此，Spring Integration Java DSL 提供了一个 IntegrationFlow 工厂，其中包含许多重载的 from() 方法。这个工厂也可以在 groovy 中使用：

@Bean
flowFromSupplier() {
    IntegrationFlow.fromSupplier({ 'bar' }) { e -> e.poller { p -> p.fixedDelay(10).maxMessagesPerPoll(1) } }
            .channel({ c -> c.queue('fromSupplierQueue') } as Function)
            .get()
}

但不幸的是，并非所有的 from() 方法都与 Groovy 结构兼容。为了解决这个问题，Spring Integration 围绕 IntegrationFlow 工厂提供了一个 Groovy DSL 工厂。它被实现为一组重载的 integrationFlow() 函数。它带有一个 GroovyIntegrationFlowDefinition 的消费者，用于将流的其余部分声明为 IntegrationFlow 闭包，以重用上述经验，并避免在末尾调用 get()。例如：

@Bean
functionFlow() {
    integrationFlow Function<byte[], String>,
            { beanName 'functionGateway' },
            {
                transform {
		            transformer Transformers.objectToString()
                    id 'objectToStringTransformer'
                }
                transform {
		            transformer { it.toUpperCase() }
                    expectedType String
                }
                splitWith {
                    expectedType Message<?>
                    function { it.payload }
                }
                splitWith {
                    expectedType Object
                    id 'splitterEndpoint'
                    function { it }
                }
                resequence()
                aggregate {
                    id 'aggregator'
                    outputProcessor { it.one }
                }
            }
}

@Bean
someFlow() {
    integrationFlow ({ 'test' },
            {
                poller { it.trigger new OnlyOnceTrigger() }
                id 'pollingSource'
            })
            {
                log LoggingHandler.Level.WARN, 'test.category'
                channel { queue 'pollerResultChannel' }
            }
}